Wie Sie bereits wissen, kann 4D Write Pro seit 4D V20 R3 in die Formate PDF/A2 und PDF/A3 (BLOG) exportieren. Abgesehen von der Signatur besteht der Hauptunterschied zwischen diesen beiden Formaten darin, dass das PDF/A3-Format Anhänge enthalten kann. Die gute Nachricht: Dank einer neuen Exportoption in 4D Write Pro ist es mit 4D V20 R4 möglich, Anhänge zu exportieren!

Archivierung hoch 10

Die PDF/A-Signatur bedeutet und garantiert, dass ein Dokument dieser Art jahrzehntelang lesbar ist, wie in diesem BLOG erläutert.
Das PDF/A3-Format ermöglicht das Einfügen von Anhängen jeglicher Art (Word, Excel, PDF, Photoshop, usw.) in das PDF/A3.
Der Vorteil ist, dass Sie alle Informationen, die Sie zu einem bestimmten Thema benötigen, in einem einzigen Dokument speichern können.

Unabhängig davon, ob es sich um ein juristisches, technisches, medizinisches, buchhalterisches, sicherheitstechnisches, bautechnisches oder sonstiges Thema handelt, wenn Sie Dokumente mit Anhängen archivieren müssen, ist PDF/A3 das richtige Format für Sie!

ein oder mehrere Anhänge

Der PDF/A3-Standard erlaubt es Ihnen, so viele Anhänge wie möglich einzufügen. Aus diesem Grund gibt es die neue Exportoption files, die vom Typ Sammlung ist.

Jedes Element dieser Sammlung ist ein Objekt mit einigen einfachen Eigenschaften, von denen einige optional sind.

Die erste und offensichtlichste ist die Eigenschaft .file vom Typ 4D.File, die die physische Datei angibt, die in die PDF-Datei aufgenommen werden soll. Sie kann jedoch auch durch die Eigenschaft .data vom Typ Text oder BLOB ersetzt werden. Diese beiden Eigenschaften schließen sich gegenseitig aus: Wenn die Eigenschaft .data vorhanden ist, wird die Eigenschaft .file ignoriert.

Die Eigenschaft .description ist optional, ebenso wie .mimeType, die im Allgemeinen aus dem Inhalt von .file oder .data abgeleitet werden kann.

Schließlich ist .name der Dateiname, der aus der PDF-Datei extrahiert wird. Dieser ist nur dann obligatorisch, wenn die Eigenschaft .data verwendet wurde und nicht die Eigenschaft .file. Andernfalls hat sie standardmäßig denselben Namen wie die in .file definierte Originaldatei!

Ein einfaches Code-Beispiel

Der folgende Code zeigt, wie man zwei physische Dateien und einen einfachen Text als Daten einfügt.

$options:={}  // empty object
$options[wk files]:=[]  // empty collection

// 1st file (based on .file)
$fileInfo:={}
$fileInfo.description:="RTF formated text"
$fileInfo.file:=File(Folder(fk data folder).path+"Alpha.rtf")
$options[wk files].push($fileInfo)

// 2nd file  (based on .file)
$fileInfo:={}
$fileInfo.description:="Png picture"
$fileInfo.file:=File(Folder(fk data folder).path+"Bravo.png")
$options[wk files].push($fileInfo)

// 3rd file (based on .data)
$fileInfo:={}
$fileInfo.name:="Charlie.txt"  // will be used for extraction
$fileInfo.description:="raw text sent as data"
$fileInfo.data:="This is some raw text to be included as enclosure in the PDF and to be extracted as 'Charlie.txt'"
$options[wk files].push($fileInfo)

WP EXPORT DOCUMENT($document; "exportWithEnclosures.pdf"; wk pdf; $options)

Hinweis: Wenn Sie das Attribut wk files verwenden, ist die Version des generierten PDF-Dokuments automatisch PDF/A3, und die Option wk pdfa version, falls vorhanden, wird ignoriert.

Nach der Ausführung sieht das PDF-Dokument wie folgt aus (mit Adobe Acrobat Reader™)

Fazit (und Fortsetzung folgt!)

Durch das Anhängen von Dokumenten innerhalb einer einzigen PDF/A3-Datei können Sie die Möglichkeiten dieses Standards voll ausschöpfen. Aber das ist noch nicht alles! Wie Sie in Kürze sehen werden, wird es auch möglich sein, elektronische Rechnungen zu erstellen, indem ein XML-Dokument als erste Datei in den Anhängen eingefügt wird! Bleiben Sie dran!