Jak již víte, od verze 4D V20 R3 umí 4D Write Pro exportovat do formátů PDF/A2 a PDF/A3 (BLOG). Kromě podpisu je hlavní rozdíl mezi těmito dvěma formáty v tom, že formát PDF/A3 může obsahovat přílohy. Dobrou zprávou je, že díky nové možnosti exportu v aplikaci 4D Write Pro je možné v aplikaci 4D V20 R4 mít při exportu přílohy!

Archivace v síle 10

Podpis PDF/A znamená a zaručuje, že dokument tohoto typu bude čitelný desítky let, jak je vysvětleno v tomto BLOGu.
Formát PDF/A3 umožňuje vkládat přílohy libovolného typu (Word, Excel, PDF, Photoshop atd.) dovnitř PDF/A3.
Výhodou je, že do jediného dokumentu můžete uložit všechny informace, které k danému tématu potřebujete.

Ať už se zabýváte oblastí práva, techniky, lékařství, účetnictví, bezpečnosti, stavebnictví, veřejných prací nebo jakoukoli jinou, pokud potřebujete archivovat dokumenty obsahující přílohy, je formát PDF/A3 tím pravým!

jedna nebo více příloh

Standard PDF/A3 umožňuje vkládat co nejvíce příloh. Proto je nová možnost exportu, .files, typu kolekce.

Každý prvek této kolekce je objekt s několika jednoduchými vlastnostmi, z nichž některé jsou volitelné.

První a nejviditelnější je vlastnost .file typu 4D.File označuje fyzický soubor, který má být do PDF zahrnut. Lze ji však nahradit vlastností .data typu text nebo BLOB. Tyto dvě vlastnosti se vylučují: pokud je přítomna vlastnost .data, bude vlastnost .file ignorována.

Vlastnost .description je nepovinná, stejně jako vlastnost .mimeType, kterou lze obecně odvodit z obsahu vlastnosti .file nebo .data.

A konečně, .name je název souboru, který bude z PDF vyjmut. Ten je povinný pouze v případě, že byla použita vlastnost .data, a nikoliv vlastnost .file. Jinak bude mít ve výchozím nastavení stejný název jako původní soubor definovaný ve vlastnosti .file!

jednoduchá ukázka kódu

Níže uvedený kód ukazuje, jak vložit dva fyzické soubory plus jednoduchý text zaslaný jako data.

$options:={}  // empty object
$options[wk files]:=[]  // empty collection

// 1st file (based on .file)
$fileInfo:={}
$fileInfo.description:="RTF formated text"
$fileInfo.file:=File(Folder(fk data folder).path+"Alpha.rtf")
$options[wk files].push($fileInfo)

// 2nd file  (based on .file)
$fileInfo:={}
$fileInfo.description:="Png picture"
$fileInfo.file:=File(Folder(fk data folder).path+"Bravo.png")
$options[wk files].push($fileInfo)

// 3rd file (based on .data)
$fileInfo:={}
$fileInfo.name:="Charlie.txt"  // will be used for extraction
$fileInfo.description:="raw text sent as data"
$fileInfo.data:="This is some raw text to be included as enclosure in the PDF and to be extracted as 'Charlie.txt'"
$options[wk files].push($fileInfo)

WP EXPORT DOCUMENT($document; "exportWithEnclosures.pdf"; wk pdf; $options)

Poznámka: pokud použijete vlastnost wk files, verze generovaného PDF bude automaticky PDF/A3a možnost wk pdfa version, pokud je přítomna, bude ignorována.

Po provedení bude dokument PDF vypadat takto (při použití aplikace Adobe Acrobat Reader™)

Závěr (a pokračování!)

Připojení dokumentů v rámci jednoho souboru PDF/A3 znamená, že můžete plně využít všech výhod, které tento standard umožňuje. Ale to není všechno! Jak brzy uvidíte, umožní také generování elektronických faktur vložením dokumentu XML jako prvního souboru v přílohách! Zůstaňte naladěni!