4D View Pro: Suchen und Ersetzen mit Code

Wenn Sie ein 4D View Pro Dokument initialisieren, müssen Sie manchmal einige Werte oder Tags darin finden und sie durch Daten aus 4D ersetzen. Jetzt ist das ein Kinderspiel mit dem VP Find Befehl. Mit diesem Befehl können Sie Daten, eine Formel oder ein Tag suchen und im gesamten Blatt oder nur in einem bestimmten Teil davon ersetzen!

Lassen Sie uns herausfinden, wie.

HDI VP-Suche

Der Befehl VP Find lässt Sie nach einem Textwert innerhalb eines bestimmten Bereichs im Text, in Formeln oder Tags eines 4D View Pro Dokuments suchen.

Wenn Sie zum Beispiel eine Suche nach dem ersten Vorkommen des Wortes „Total“ im Text der Zellen durchführen möchten, wobei die Groß- und Kleinschreibung beachtet werden muss:

$range:=VP All("ViewProArea")
// find the first cell that contains the word 'Total' in the current sheet
$result :=VP Find($range; "Total")
// Make the cell background yellow for the found cells
VP SET CELL STYLE ($result; New object("backColor"; "yellow"))

Jetzt können Sie Ihre Suche verfeinern, um alle Zellen zu finden, die „Total“ enthalten, indem Sie die all Eigenschaft:

$range:=VP All("ViewProArea")
$condition :=New object
// Search in all values in the range
$condition .all:=True
// Find all cells containing the word 'Total' in the current sheet
$result :=VP Find($range; "Total"; $condition)
// Make the cell background yellow for the found cells
VP SET CELL STYLE ($result; New object("backColor"; "yellow"))

• Wenn Sie eine Suche nach „Total“ durchführen möchten, ohne die Groß-/Kleinschreibung zu berücksichtigen, ändern Sie einfach die flags Eigenschaft:

$range:=VP All("ViewProArea")
$condition :=New object
// Search the entire sheet
$condition .all:=True
// Search cells containing the word "Total" without considering the case
$condition .flags:=vk find flag ignore case
// Find all cells containing only the word 'Total' in the current sheet
$result :=VP Find($range; "Total"; $condition)
// Make the cell background yellow for the found cells
VP SET CELL STYLE ($result; New object("backColor"; "yellow"))


• Wenn Sie alle gefundenen „Total“-Wörter durch „4D“ ersetzen wollen, fügen Sie einen Parameter mit dem Ersatztext hinzu:

$range:=VP All("ViewProArea")
$condition :=New object
// Search the entire sheet
$condition .all:=True
// Search cells containing the word "Total" without considering the case
$condition .flags:=vk find flag ignore case
// Replace text in all cells containing only 'Total' with "4D"
$result :=VP Find($range; "Total"; $condition; "4D")
// Make the cell background yellow for the found cells
VP SET CELL STYLE ($result; New object("backColor"; "yellow"))

Dies sind natürlich nur einige der Möglichkeiten, die der VP Find Befehl.

Im Doc Center finden Sie weitere Informationen, z. B. wie Sie Werte mit Platzhaltern finden, in Formeln suchen und vieles mehr.