4D Write Pro je základní produkt pro vytváření obchodních dokumentů. Proto vám s každou novou verzí přinášíme další funkce, které vám usnadní práci, a tentokrát 4D v19 R8 přináší do 4D Write Pro plovoucí textová pole.

Pokud tedy musíte používat textová pole, řekněme pro vytváření firemních dopisů v souladu s firemní identitou, můžete se do toho hned pustit.

Textové rámečky v aplikaci 4D Write Pro

Textové boxy mohou být někomu povědomé, ale možná bude užitečné připomenout si, co to je!

Textový rámeček je plovoucí textová oblast libovolné velikosti obsahující text, obrázky nebo tabulky! Lze je použít velmi různými způsoby, například k umístění adresy na určité místo na papíře, aby se v okně obálky zřetelně zobrazovala.

 

 

 

Jak vytvořit textový rámeček?

Jako obvykle je možných několik řešení; nejjednodušší je použít rozhraní. K tomu jsou k dispozici nová tlačítka na panelu nástrojů a na postranním panelu.

Po vytvoření lze textová pole přesouvat kliknutím na jejich okraje a měnit jejich velikost pomocí úchytů.

Atributy a obsah textového pole

Textové boxy mají své vlastní atributy. Tyto atributy lze měnit programováním i jednoduše pomocí rozhraní.

U každého textového pole můžete zvolit typ rámečku, barvu, tloušťku a barvu pozadí.

Pokud jde o obsah, můžete do textových polí vkládat text, obrázky a tabulky, které samozřejmě mohou obsahovat vzorce.

Nové příkazy a standardní akce

Byly vytvořeny nové příkazy a standardní akce pro programové vytváření a odstraňování textových polí.

Začněme příkazy!

Příkazy

Byly vytvořeny dva nové příkazy pro vkládání a odstraňování textových polí…

• WP nové textové pole
• WP ODSTRANIT TEXTOVÉ POLE

 

… a mnoho (mnoho) stávajících příkazů bylo vylepšeno tak, aby mohly tyto nové objekty přijímat jako parametry!

Zde jsou některé z nich:

• WP NASTAVIT ATRIBUTY
• WP Získat prvky
• WP Najít vše
• WP Získat pozici
• WP Získat vzorce
• WP Získat text

Ukázka kódu

V tomto příkladu chceme vytvořit textové pole, které má následující vlastnosti:

Jeho obsah by měl mít rozměry 10 cm x 3,5 cm, vnitřní okraje 0,5 cm a měl by být umístěn 8 cm a 4,5 cm od levého horního rohu stránky. Nakonec by měl být označen modrými tečkovanými okraji a mít zaoblené rohy.

 

K tomu je třeba napsat následující kód.

// #1 create the the text box
$textBox:=WP New text box(WParea; 1)

// #2 define some text box attributes
WP SET ATTRIBUTES($textBox; wk id; "AddressArea")
// define anchoring and position
WP SET ATTRIBUTES($textBox; wk anchor origin; wk paper box)
WP SET ATTRIBUTES($textBox; wk anchor horizontal align; wk left; wk vertical align; wk top)
WP SET ATTRIBUTES($textBox; wk anchor horizontal offset; "8cm"; wk anchor vertical offset; "4.5cm")

// define size and style
WP SET ATTRIBUTES($textBox; wk padding; "0.5cm")  // inside margins
WP SET ATTRIBUTES($textBox; wk width; "10cm"; wk height; "3.5cm")
WP SET ATTRIBUTES($textBox; wk border style; wk dashed; wk border color; "Blue"; wk border width; "1pt"; wk border radius; "10pt")
WP SET ATTRIBUTES($textBox; wk vertical align; wk center)

// #3: insert some formulas inside the text box 
WP INSERT FORMULA($textBox; Formula(This.data.fullName); wk append)
WP INSERT BREAK($textBox; wk paragraph break; wk append)
WP INSERT FORMULA($textBox; Formula(This.data.fullAddress); wk append)

// #4: Set style to the content of the text box
WP SET ATTRIBUTES($textBox; wk font; "Arial"; wk font bold; wk true; wk font size; "18pt")

Necítíte se dnes na programování? Žádný problém; standardní akce jsou tu pro vás!

Standardní akce (spojené s nabídkami nebo tlačítky)

„insertTextBox“ je nová standardní akce pro vytváření textových polí, ale předponu textbox/ lze použít i pro nastavení parametrů, jako jsou okraje, okraje, výplň, pozadí atd.

Zde je několik příkladů:

• textBox/marginLeft
• textBox/paddingTop
• textBox/borders
• textBox/remove

 

Nebo si můžete vytvořit vlastní nabídku…

$menu:=Create menu
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderStyle")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderColor")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderWidth")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/backgroundColor")

$value:=Dynamic pop up menu($menu)
// no need to check the $value, all items are based on standard actions!
// just don't forget to release the menu to avoid memory leaks!
RELEASE MENU($menu)

A zde je vytvořená nabídka:

EXPORT DO PDF, SVG!

Většina exportních formátů samozřejmě tato textová pole zohledňuje. V případě exportu do HTML jen připomínáme, že ukotvení musí být založeno na režimu Vloženo, nikoliv na režimu Stránka!

Závěr

Tato nová funkce je významným průlomem v aplikaci 4D Write Pro. Umožňuje vytvářet propracovanější dokumenty a přitom zůstává velmi jednoduchá na používání.