4D Write Pro es un producto esencial para la creación de documentos comerciales. Es por eso que con cada nueva versión, le damos más funcionalidades para ayudarle en su trabajo, y esta vez, 4D v19 R8 trae cajas de texto flotantes a 4D Write Pro.
Así que si está obligado a utilizar cajas de texto, por ejemplo, para crear cartas con la identidad de la empresa, puede empezar de inmediato.
Las cajas de texto pueden ser familiares para algunos, ¡pero puede ser útil recordar lo que son!
Una caja de texto es un área de texto flotante de cualquier tamaño que contiene texto, imágenes o tablas. Se pueden utilizar de formas muy diversas, por ejemplo, para colocar una dirección en un lugar concreto del papel para que aparezca claramente en la ventana del sobre.
¿Cómo crear unA caja de texto?
Como siempre, hay varias soluciones posibles; la más sencilla es utilizar la interfaz. Hay nuevos botones disponibles para ello en la barra de herramientas y en la barra lateral.
Una vez creadas, las cajas de texto pueden desplazarse haciendo clic en sus bordes y redimensionarse con los tiradores.
Atributos y contenido de lAs cajas de texto
Los cuadros de texto tienen sus propios atributos. Estos atributos pueden modificarse mediante programación y simplemente utilizando la interfaz.
Puede elegir el tipo de borde, el color, el grosor y el color de fondo de cada caja de texto.
En cuanto al contenido, puede utilizar las cajas de texto para insertar texto, imágenes y tablas, todo lo cual puede, por supuesto, contener fórmulas.
Nuevos comandos y acciones estándar
Se han creado nuevos comandos y acciones estándar para crear y eliminar la cajas de texto por programación.
¡Empecemos con los comandos!
Comandos
Se han creado dos nuevos comandos para insertar y eliminar cajas de texto…
- WP new text box
- WP DELETE TEXTBOX
… Y muchos (muchos) comandos existentes han sido mejorados para tomar estos nuevos objetos como parámetros.
Aquí están algunos de ellos:
- WP SET ATTRIBUTES
- WP Get elements
- WP Find all
- WP Get position
- WP Get formulas
- WP Get text
Ejemplo de código
En este ejemplo, queremos crear una caja de texto que tenga las siguientes características:
Su contenido debe medir 10 cm x 3,5 cm, tener márgenes interiores de 0,5 cm y estar situado a 8 cm y 4,5 cm de la esquina superior izquierda de la página. Por último, debe tener los bordes punteados en azul y las esquinas redondeadas.
Para ello, aquí tiene el código que debe escribir.
// #1 create the the text box
$textBox:=WP New text box(WParea; 1)
// #2 define some text box attributes
WP SET ATTRIBUTES($textBox; wk id; "AddressArea")
// define anchoring and position
WP SET ATTRIBUTES($textBox; wk anchor origin; wk paper box)
WP SET ATTRIBUTES($textBox; wk anchor horizontal align; wk left; wk vertical align; wk top)
WP SET ATTRIBUTES($textBox; wk anchor horizontal offset; "8cm"; wk anchor vertical offset; "4.5cm")
// define size and style
WP SET ATTRIBUTES($textBox; wk padding; "0.5cm") // inside margins
WP SET ATTRIBUTES($textBox; wk width; "10cm"; wk height; "3.5cm")
WP SET ATTRIBUTES($textBox; wk border style; wk dashed; wk border color; "Blue"; wk border width; "1pt"; wk border radius; "10pt")
WP SET ATTRIBUTES($textBox; wk vertical align; wk center)
// #3: insert some formulas inside the text box
WP INSERT FORMULA($textBox; Formula(This.data.fullName); wk append)
WP INSERT BREAK($textBox; wk paragraph break; wk append)
WP INSERT FORMULA($textBox; Formula(This.data.fullAddress); wk append)
// #4: Set style to the content of the text box
WP SET ATTRIBUTES($textBox; wk font; "Arial"; wk font bold; wk true; wk font size; "18pt")¿No está de ánimo para programar hoy? No hay problema; ¡Las acciones estándar están para usted!
Acciones estándar (asociadas a menús o A botones)
«insertTextBox» es la nueva acción estándar para crear cajas de texto, pero el prefijo textbox/ también puede utilizarse para definir parámetros como las márgenes, los bordes, el relleno, el fondo, etc.
He aquí algunos ejemplos:
- textBox/marginLeft
- textBox/paddingTop
- textBox/borders
- textBox/remover
O puede crear su propio menú…
$menu:=Create menu
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderStyle")
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderColor")
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderWidth")
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/backgroundColor")
$value:=Dynamic pop up menu($menu)
// no need to check the $value, all items are based on standard actions!
// just don't forget to release the menu to avoid memory leaks!
RELEASE MENU($menu)Y aquí está el menú creado:
¡EXPORTAR A PDF, SVG!
Por supuesto, la mayoría de los formatos de exportación consideran estos cajas de texto. En el caso de la exportación HTML, sólo recuerde que el anclaje debe basarse en el modo Anidado, no en el ¡Modo Página!
Conclusión
Esta nueva funcionalidad es un avance significativo de 4D Write Pro. Permite la creación de documentos más elaborados sin dejar de ser muy fácil de usar.