Por vezes, é necessário exibir diferentes tabelas de informação num único documento. Para uma melhor visibilidade, é frequentemente necessário exibi-las em diferentes folhas. Neste caso, é necessário criar, renomear, esconder ou remover uma folha, ou simplesmente saber em que folha o utilizador se encontra actualmente.
Com 4D v19 R2, pode gerir as folhas nos seus documentos 4D View Pro por programação.
Por defeito, um novo documento só tem uma folha:
Adição de folhas de trabalho
Há duas maneiras de criar novas folhas de trabalho:
- com o centro doc VP SET SHEET COUNT pode definir de imediato o número de folhas de que necessita. Por exemplo, se precisar de três folhas:
VP SET SHEET COUNT("ViewProArea"; 3)
Cada folha tem um índice que se pode utilizar nos comandos. A indexação começa em 0, portanto aqui o índice da “Folha1” é 0, o índice da “Folha2” é 1, e assim por diante… Tenha em mente que o índice é a posição da folha na barra de tabulação, e muda quando adiciona, retira ou altera a ordem das suas folhas.
- com o comando VP ADD SHEET pode inserir uma folha com um nome personalizado num índice específico. Por exemplo, se precisar de inserir uma nova folha com o nome “Total primeiro trimestre”:
VP ADD SHEET("ViewProArea"; 0; "Total primeiro trimestre")Porque inserimos uma nova folha, os índices mudaram. O índice do “Total primeiro trimestre” é 0, o índice da “Folha1” é agora 1, e assim por diante…
reNomeando uma Ficha de Trabalho
Por defeito, as folhas de um documento View Pro são designadas “SheetX”. Para lhes dar nomes que sejam mais relevantes para os seus utilizadores, utilize o VP SET SHEET NAME comando. No nosso exemplo, podemos mudar os nomes “Sheet1”, “Sheet2”, “Sheet3” para “Janeiro”, “Fevereiro” e “Março”:
VP SET SHEET NAME("ViewProArea"; "Janeiro"; 1)
VP SET SHEET NAME ("ViewProArea"; "Fevereiro"; 2)
VP SET SHEET NAME ("ViewProArea"; "Março"; 3)
seleccionando uma folha de trabalho
Pode alterar a folha seleccionada com VP SET CURRENT SHEET. Por exemplo, se adicionarmos uma nova folha de trabalho e a seleccionarmos:
// find the last position by counting the sheets
$lastPosition:=VP Get sheet count("ViewProArea")
// add new sheet at the last position
VP ADD SHEET ("ViewProArea"; $lastPosition ; "Total segundo trimestre")
// select the new sheet
VP SET CURRENT SHEET ("ViewProArea"; $lastPosition )
Esconder uma folha de trabalho
Se precisar de ocultar uma folha porque contém apenas informação para cálculo, utilize VP SET SHEET OPTIONS. No nosso exemplo, se quisermos mostrar apenas as folhas “Total X trimestre”, e utilizar as outras apenas para cálculos:
$options:=New object
$options .visible:=False
VP SET SHEET OPTIONS ("ViewProArea"; $options; 1)
VP SET SHEET OPTIONS ("ViewProArea"; $options; 2)
VP SET SHEET OPTIONS ("ViewProArea"; $options; 3)
E verifique o centro doc para mais detalhes!