4D Write Pro è un prodotto essenziale per la creazione di documenti aziendali. Per questo motivo, ad ogni rilascio di funzionalità, ne vengono aggiunte di nuove per rendere il vostro lavoro ancora più interessante. Questa volta, 4D v19 R8 introduce in 4D Write Pro le caselle di testo fluttuanti.

Quindi, se dovete usare le caselle di testo, ad esempio per creare lettere aziendali in conformità con l’identità dell’azienda, potete iniziare subito.

Caselle di testo di 4D Write Pro

Le caselle di testo possono risultare familiari ad alcuni, ma può essere utile ricordare cosa sono!

Una casella di testo è un’area di testo fluttuante di qualsiasi dimensione contenente testo, immagini o tabelle! Possono essere utilizzate in modi molto diversi, ad esempio per posizionare un indirizzo in un punto specifico della carta in modo che appaia chiaramente nella finestra della busta.

 

 

 

Come creare una casella di testo?

Come sempre, sono possibili diverse soluzioni; la più semplice è quella di utilizzare l’interfaccia. A questo scopo sono disponibili nuovi pulsanti nella barra degli strumenti e nella barra laterale.

Una volta create, le caselle di testo possono essere spostate facendo clic sui loro bordi e ridimensionate con le maniglie.

Attributi e contenuto delle caselle di testo

Le caselle di testo hanno i propri attributi. Questi attributi possono essere modificati tramite la programmazione o semplicemente utilizzando l’interfaccia.

È possibile scegliere il tipo di bordo, il colore, lo spessore e il colore di sfondo di ogni casella di testo.

Per quanto riguarda il contenuto, è possibile utilizzare le caselle di testo per inserire testo, immagini e tabelle, che possono ovviamente contenere formule.

Nuovi comandi e azioni standard

Sono stati creati nuovi comandi e azioni standard per creare ed eliminare programmaticamente le caselle di testo.

Cominciamo con i comandi!

Comandi

Sono stati creati due nuovi comandi per inserire ed eliminare le caselle di testo…

• WP nuova casella di testo
• WP CANCELLA CASELLA DI TESTO

 

… e molti (molti) comandi esistenti sono stati migliorati per accettare questi nuovi oggetti come parametri!

Eccone alcuni:

• WP IMPOSTA ATTRIBUTI
• WP Ottieni elementi
• WP Trova tutto
• WP Ottieni posizione
• WP Ottieni formule
• WP Ottieni testo

Esempio di codice

In questo esempio, vogliamo creare una casella di testo con le seguenti caratteristiche:

Il suo contenuto deve misurare 10 cm x 3,5 cm, avere margini interni di 0,5 cm ed essere posizionato a 8 cm e 4,5 cm dall’angolo superiore sinistro della pagina. Infine, deve avere i bordi punteggiati di blu e gli angoli arrotondati.

 

Per farlo, ecco il codice da scrivere.

// #1 create the the text box
$textBox:=WP New text box(WParea; 1)

// #2 define some text box attributes
WP SET ATTRIBUTES($textBox; wk id; "AddressArea")
// define anchoring and position
WP SET ATTRIBUTES($textBox; wk anchor origin; wk paper box)
WP SET ATTRIBUTES($textBox; wk anchor horizontal align; wk left; wk vertical align; wk top)
WP SET ATTRIBUTES($textBox; wk anchor horizontal offset; "8cm"; wk anchor vertical offset; "4.5cm")

// define size and style
WP SET ATTRIBUTES($textBox; wk padding; "0.5cm")  // inside margins
WP SET ATTRIBUTES($textBox; wk width; "10cm"; wk height; "3.5cm")
WP SET ATTRIBUTES($textBox; wk border style; wk dashed; wk border color; "Blue"; wk border width; "1pt"; wk border radius; "10pt")
WP SET ATTRIBUTES($textBox; wk vertical align; wk center)

// #3: insert some formulas inside the text box 
WP INSERT FORMULA($textBox; Formula(This.data.fullName); wk append)
WP INSERT BREAK($textBox; wk paragraph break; wk append)
WP INSERT FORMULA($textBox; Formula(This.data.fullAddress); wk append)

// #4: Set style to the content of the text box
WP SET ATTRIBUTES($textBox; wk font; "Arial"; wk font bold; wk true; wk font size; "18pt")

Non avete voglia di programmare oggi? Nessun problema: le azioni standard sono lì per voi!

Azioni standard (associate a menu o pulsanti)

“insertTextBox” è la nuova azione standard per creare caselle di testo, ma il prefisso textbox/ può essere usato anche per impostare parametri come margini, bordi, padding, sfondo, ecc.

Ecco alcuni esempi:

• textBox/margineSinistra
• textBox/paddingTop
• textBox/bordersAll
• textBox/rimuovi

 

Oppure si può creare il proprio menu…

$menu:=Create menu
APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderStyle")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderColor")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/borderWidth")

APPEND MENU ITEM($menu; ak standard action title)
SET MENU ITEM PROPERTY($menu; -1; Associated standard action name; "textBox/backgroundColor")

$value:=Dynamic pop up menu($menu)
// no need to check the $value, all items are based on standard actions!
// just don't forget to release the menu to avoid memory leaks!
RELEASE MENU($menu)

Ed ecco il menu creato:

ESPORTA IN PDF, SVG!

Naturalmente, la maggior parte dei formati di esportazione considera queste caselle di testo. Nel caso dell’esportazione in HTML, è sufficiente ricordare che l’ancoraggio deve essere basato sulla modalità Embedded, non sulla modalità Page!

Conclusione

Questa nuova funzione rappresenta una svolta significativa in 4D Write Pro. Permette di creare documenti più elaborati, pur rimanendo molto semplice da usare.