Tabellenkalkulationen sind vielseitige Werkzeuge. Von Dashboards bis hin zu Input/Output UI. Tabellenkalkulationen von 4D View Pro können schnell viele Situationen lösen, mit denen Ihre Endanwender konfrontiert werden.
Wir haben Ihnen bereits erklärt, wie Sie die Tabellenfunktion von 4D View Pro zur Anzeige und Änderung von Datensammlungen nutzen können. Bei der Verwendung von 4D View Pro Tabellen müssen Sie eventuell später Spalten hinzufügen oder entfernen, je nach Bedarf des Endanwenders. Zu diesem Zweck verfügt 4D View Pro ab 4D v19 R7 über mehrere neue Befehle zur Verwaltung Ihrer Tabellenspalten und -zeilen. Schauen wir uns an, wie das funktioniert.
Der erste Schritt vor dem Hinzufügen oder Entfernen von Spalten ist die Erstellung einer 4D View Pro Tabelle. Für die folgenden Beispiele verwenden wir eine 4D View Pro Tabelle, die Daten aus einer Datenbanktabelle namens „People“ anzeigt:
$context:=New object
$context.people:=ds.People.all().toCollection()
VP SET DATA CONTEXT("ViewProArea"; $context)
$parameter:=New object
$parameter.tableColumns:=New collection
$parameter.tableColumns.push(New object("name"; "Phone"; "dataField"; "Phone"))
$parameter.tableColumns.push(New object("name"; "Email"; "dataField"; "email"))
$parameter.tableColumns.push(New object("name"; "Country"; "dataField"; "Country"))
VP CREATE TABLE(VP Cells("ViewProArea"; 2; 1; 3; 1); "PeopleTable"; "people"; $parameter)
Einfügen von Spalten in eine Tabelle
Der VP INSERT TABLE COLUMNS Befehl ermöglicht Ihnen das Einfügen einer Spalte, wann immer Sie diese in Ihrer Tabelle benötigen. Wenn Sie z.B. 2 neue Spalten vor der ersten Spalte der 4D View Pro Tabelle einfügen möchten:
VP INSERT TABLE COLUMNS("ViewProArea"; "PeopleTable"; 0; 2;vk table insert before)
// 0 indicate the first column of the table.
Es werden 2 leere Spalten in die Tabelle eingefügt. Wir füllen sie nun mit den Feldern Vorname und Nachname dank des Befehls VP SET TABLE COLUMN ATTRIBUTES:
$param:=New object
// Bind the column to the Firstname field from the datacontext
$param.dataField:="Firstname"
// Change the default name of the column to "First name"
$param.name:="First name"
VP SET TABLE COLUMN ATTRIBUTES("ViewProArea"; "PeopleTable"; 0; $param)
$param:=New object
// Bind the column to the Lastname field from the datacontext
$param.dataField:="Lastname"
// Change the default name of the column to "Last name"
$param.name:="Last name"
VP SET TABLE COLUMN ATTRIBUTES("ViewProArea"; "PeopleTable"; 1; $param)
Einfügen und Entfernen von Zeilen
Auf die gleiche Weise können Sie den Befehl VP INSERT TABLE ROWS verwenden, um leere Zeilen in Ihre Tabelle einzufügen:
VP INSERT TABLE ROWS("ViewProArea"; "PeopleTable"; 1; 2)
Denken Sie daran, dass VP INSERT TABLE ROWS nicht nur grafische Elemente hinzufügt wie VP INSERT TABLE COLUMNS. VP INSERT TABLE COLUMNS fügt nur Spalten in das Blatt ein, VP INSERT TABLE ROWS fügt Zeilen in das Blatt ein und erstellt 2 neue Zeilen in der Sammlung Ihres Datenkontexts.
In unserem Beispiel, wenn Sie VP Get data context verwenden, erhalten Sie Ihre Personensammlung mit 2 neuen leeren Zeilen, people[1] und people[2]:
$data:=VP Get data context("ViewProArea")
Wenn Sie einige Informationen in Ihre leeren Zellen schreiben:
Die Attribute, die Ihren neuen Informationen entsprechen, werden automatisch hinzugefügt. Hier wurde people[1] mit Details gefüllt:
$data:=VP Get data context("ViewProArea")
Wenn Sie einige Zeilen entfernen, funktioniert dies auf die gleiche Weise. Wenn Sie z.B. alle Zeilen bis auf die ersten 2 entfernen, verschwinden die Zeilen grafisch und im Datenkontext:
VP REMOVE TABLE ROWS("ViewProArea"; "contexttest"; 2; 10)
$data:=VP Get data context("ViewProArea")
Die Assoziation zwischen Datenkontext und Tabelle ist also ein einfacher Weg, Ihre Sammlungen in 4D View Pro zu verwalten!
Schauen Sie sich diese Funktion mit dem obigen HDI an und lesen Sie die Dokumentation für weitere Details!