4D 21 und AI Kit: Das Denken und Handeln von Anwendungen neu definieren

Mit 4D 21 macht KI einen großen Sprung nach vorn. Das Herzstück dieser Entwicklung ist der Werkzeugaufruf des AI Kits, eine wichtige Ergänzung, die die Art und Weise, wie Sie KI in Ihre Anwendungen integrieren, verändert.

Mit Tool Calling können Sie die Fähigkeiten des Modells erweitern, indem Sie Ihre eigenen Methoden oder Funktionen registrieren, die die KI bei Bedarf automatisch aufrufen kann. Das bedeutet, dass der Chat-Helfer nicht mehr jede Interaktion manuell bearbeiten muss, sondern automatisch Ihre Handler aufruft, was Ihnen sowohl Flexibilität als auch Kontrolle gibt.

Warum das wichtig ist

Unsere Implementierung überlässt den Entwicklern die Kontrolle. Sie entscheiden, welche Tools vorhanden sind und welche Daten gemeinsam genutzt werden; es gibt keinen direkten Zugriff der KI auf Ihre Datenbank. Sie deklarieren die Tools, definieren ihre Parameter und legen genau fest, welche Daten sie zurückgeben sollen. Auf diese Weise sind Ihre Daten geschützt, während die KI mit den von Ihnen gewünschten Ergebnissen arbeiten kann.

Der Aufruf von Werkzeugen öffnet auch die Tür zur Retrieval-Augmented Generation (RAG). Bei RAG verlässt sich das Modell nicht nur auf sein eigenes Wissen. Stattdessen kann es dynamisch Informationen aus externen Quellen abrufen, z. B. aus Ihrer 4D Datenbank, bevor es eine Antwort erzeugt. Das Ergebnis sind Antworten, die nicht nur intelligent und natürlich sind, sondern sich auch auf Ihren realen Geschäftskontext stützen.

KI-Tool für Anrufe in Konversationen

Eine wichtige Neuerung im AI Kit ist die Möglichkeit, dass der Assistent während eines Gesprächs automatisch Tools aufruft. Ein Tool ist eine benutzerdefinierte, vom Entwickler registrierte Funktion, die vom Modell ausgelöst werden kann, wenn bestimmte Bedingungen erfüllt sind. Dadurch wird Ihr Assistent viel dynamischer und kann spezielle Aufgaben ohne manuelles Eingreifen ausführen.

So können Sie beispielsweise ein Tool erstellen, das Informationen über eine Person zurückgibt, Rechnungen storniert, E-Mails versendet oder Bestellungen bestätigt. Damit wird Ihr Assistent zu einer neuen Schnittstelle für die Interaktion mit den von Ihrer 4D App angebotenen Diensten. Und das Beste daran? Dies kann ausschließlich über eine auf Eingabeaufforderungen basierende Benutzeroberfläche geschehen, was genau der Art und Weise entspricht, wie die nächste Generation von Nutzern mit Software interagieren möchte.

Beispiel: Erstellen eines „GetPeopleInfo“-Tools

Hier ein praktisches Beispiel, das zeigt, wie man ein Tool mit AI Kit registriert und verwendet:

• Erstellen Sie zunächst eine Klasse Tool_GetPeopleInfo, die das Tool beschreibt:

// --- Tool Definition ---
property tool:={}

Class constructor
  // We describe the "GetPeopleInfo" tool in json format:
  This.tool.name:="GetPeopleInfo"
  This.tool.description:="It returns information about the person based on their first and last name."
  This.tool.parameters:={type: "object"; properties: {}}
  This.tool.parameters.properties.firstname:={type: "string"; description: "First name of the person sought"}
  This.tool.parameters.properties.lastname:={type: "string"; description: "Last name of the person sought"}
	
Function handler($info : Object) : Text
	$result:=ds.People.query("Firstname=:1 and Lastname=:2"; $info.firstname; $info.lastname)
	// Returns the person information
	return $result.length>0 ? JSON Stringify($result[0].toObject()) : "This person is unknown"

• Dann registrieren Sie das Tool mit dem Chat-Helfer:

var $client:=cs.AIKit.OpenAI.new($openAIKey)
var $chatHelper:=$client.chat.create("you are an HR assistant.")

// --- Tool Registration ---
// We register the tool with the chat helper.
// This allows the model to automatically invoke it when a request matches.
$chatHelper.registerTool(cs.Tool_GetPeopleInfo.new())

var $result:=$chatHelper.prompt("What is Faye Back's address?")
//$result.choice.message.text="Faye Back's address is Earl Boulevard (178), Lanesville, 12450, USA.

Wenn der Benutzer fragt:„Wie lautet die Adresse von John Smith?„, beschließt das Modell, das Tool „GetPeopleInfo“ aufzurufen, da es Zugriff auf die Tooldefinition hat. Die Funktion handler wird von AIKit automatisch mit den angegebenen Parametern aufgerufen. Das Modell empfängt die Antwort, integriert sie in die Konversation und gibt die formatierte Antwort zurück. All dies geschieht ohne manuelle Kodierung für jede Abfrage.

Über das Beispiel hinaus: Ausweitung der Anwendungsfälle

Das Potenzial von Tool Calling geht weit über das Abrufen von Daten hinaus. Hier sind einige Beispiele, was Sie tun können:

• Stornieren von Rechnungen auf der Grundlage einer Benutzeranfrage.

• Automatisierte E-Mails mit benutzerdefinierten Inhaltenversenden.

• Bestellungen vor der Verarbeitungvalidieren.

• Auslösen von Workflows innerhalb Ihrer 4D App.

Mit diesen Tools wird Ihr Assistent zu einer leistungsstarken Schnittstelle für die Funktionen Ihrer App, zu einer natürlichsprachlichen Benutzeroberfläche für Ihre Dienstleistungen. Das ist nicht nur ein Nice-to-have, sondern die Art und Weise, wie die nächste Generation mit Software interagieren möchte.

Fazit

Mit dem AI Kit von 4D 21 können Sie die Funktionen des Modells nahtlos mit Ihrer eigenen Logik erweitern. Durch die Verknüpfung von KI mit Ihren 4D Methoden oder Funktionen können Sie dem Assistenten direkten Zugang zu Ihren Daten und Prozessen gewähren, wodurch seine Antworten nicht nur intelligenter werden, sondern auch perfekt an Ihre geschäftlichen Anforderungen angepasst sind. Beachten Sie, dass nicht alle Modelle diese Funktionalität unterstützen.