4D 21 e AI Kit: Redefinir a forma como as aplicações pensam e actuam

Com 4D 21, a IA dá um salto gigante. No coração dessa evolução está a chamada de ferramenta do AI Kit, uma adição massiva que transforma a maneira como integra a IA em suas aplicações.

A chamada de ferramentas permite estender as capacidades do modelo registando os seus próprios métodos ou funções, que a IA pode chamar automaticamente quando relevante. Isto significa que, em vez de tratar manualmente todas as interações, o assistente de conversação invoca automaticamente os seus manipuladores, dando-lhe flexibilidade e controlo.

Porque é que isto é importante

A nossa implementação coloca os programadores no controlo. Você decide que ferramentas existem e que dados são partilhados, não há acesso direto da IA à sua base de dados. O utilizador declara as ferramentas, define os respectivos parâmetros e determina exatamente quais os dados a devolver. Isto protege os seus dados e permite que a IA trabalhe com os resultados da sua escolha.

A chamada de ferramentas também abre a porta à Geração Aumentada por Recuperação (RAG). Na RAG, o modelo não se baseia apenas no seu próprio conhecimento. Em vez disso, pode recuperar dinamicamente informação de fontes externas, como a base de dados 4D, antes de gerar uma resposta. O resultado são respostas que não são apenas inteligentes e naturais, mas baseadas no seu contexto de negócios do mundo real.

Ferramenta AI chamando Invocação em Conversas

Uma inovação chave em AI Kit é permitir que o assistente invoque automaticamente ferramentas durante as conversas. Uma ferramenta é uma função personalizada registada pelo programador que pode ser acionada pelo modelo quando determinadas condições são cumpridas. Isto torna o seu assistente muito mais dinâmico, capaz de efetuar tarefas especializadas sem intervenção manual.

Por exemplo, pode criar uma ferramenta para retornar informação sobre uma pessoa, cancelar facturas, enviar emails, validar pedidos – essencialmente transformando seu assistente numa nova interface para interagir com os serviços que sua app 4D oferece. E a melhor parte? Isso pode acontecer puramente através de uma UI baseada em prompts, que é exatamente como a próxima geração de usuários espera interagir com software.

Exemplo: Criando uma ferramenta “GetPeopleInfo

Aqui está um exemplo prático que mostra como registar e utilizar uma ferramenta com o AI Kit:

• Primeiro, crie uma classe Tool_GetPeopleInfo que descreva a ferramenta:

// --- Tool Definition ---
property tool:={}

Class constructor
  // We describe the "GetPeopleInfo" tool in json format:
  This.tool.name:="GetPeopleInfo"
  This.tool.description:="It returns information about the person based on their first and last name."
  This.tool.parameters:={type: "object"; properties: {}}
  This.tool.parameters.properties.firstname:={type: "string"; description: "First name of the person sought"}
  This.tool.parameters.properties.lastname:={type: "string"; description: "Last name of the person sought"}
	
Function handler($info : Object) : Text
	$result:=ds.People.query("Firstname=:1 and Lastname=:2"; $info.firstname; $info.lastname)
	// Returns the person information
	return $result.length>0 ? JSON Stringify($result[0].toObject()) : "This person is unknown"

• Depois, registe a ferramenta com o auxiliar de conversação:

var $client:=cs.AIKit.OpenAI.new($openAIKey)
var $chatHelper:=$client.chat.create("you are an HR assistant.")

// --- Tool Registration ---
// We register the tool with the chat helper.
// This allows the model to automatically invoke it when a request matches.
$chatHelper.registerTool(cs.Tool_GetPeopleInfo.new())

var $result:=$chatHelper.prompt("What is Faye Back's address?")
//$result.choice.message.text="Faye Back's address is Earl Boulevard (178), Lanesville, 12450, USA.

Quando o utilizador pergunta“Qual é o endereço de John Smith?“, o modelo decide chamar a ferramenta “GetPeopleInfo” porque tem acesso à definição da ferramenta. A função handler é chamada automaticamente pelo AIKit com os parâmetros fornecidos. O modelo recebe a resposta, integra-a na conversação e devolve a resposta formatada. Tudo isso acontece sem codificação manual para cada consulta.

Além do exemplo: Expansão dos casos de uso

O potencial da chamada de ferramenta vai muito além da recuperação de dados. Aqui estão alguns exemplos do que pode ser feito:

• Cancelar facturas com base num pedido do utilizador.

• Enviar e-mails automáticos com conteúdo personalizado.

• Validar encomendas antes do processamento.

• Acionar fluxos de trabalho dentro de sua app 4D.

Essas ferramentas permitem que seu assistente se torne uma interface poderosa para a funcionalidade de seu app, uma UI de linguagem natural para seus serviços. Isso não é apenas uma coisa boa de se ter: é como a próxima geração espera interagir com software.

conclusão

A ferramenta de IA chamada em 4D 21’s AI Kit lhe permite estender as capacidades do modelo com sua própria lógica. Ao ligar a IA aos seus métodos ou funções 4D, pode dar ao assistente acesso direto aos seus dados e processos, tornando as suas respostas não só mais inteligentes mas também perfeitamente adaptadas às suas necessidades de negócio. Note que nem todos os modelos suportam esta funcionalidade.