Il lavoro con gli eventi del calendario è una parte fondamentale di molte applicazioni aziendali. Che si tratti di organizzare una riunione di gruppo o di gestire il ciclo di vita di un evento, è essenziale poter creare, aggiornare ed eliminare gli eventi in modo programmatico.
In questo post del blog illustreremo come eseguire queste operazioni utilizzando le classi Office365.calendar o Google.calendar fornite in 4D 20 R10, alimentate dalle API Microsoft Graph e Google Calendar.
Gestione degli eventi del calendario HDI
Vediamo come è semplice creare, aggiornare ed eliminare una riunione in Microsoft o Google Calendar utilizzando 4D NetKit, con l’esempio seguente.
Connessione all’account
Come al solito, prima di utilizzare le API di Google o Microsoft, creeremo un oggetto di connessione OAuth 2.0:
Per le API di Google:
var $oAuth2:=cs.NetKit.OAuth2Provider.new($googleCredentials)
var $google:=cs.NetKit.Google.new($oAuth2)Per le API Microsoft:
var $oAuth2:=cs.NetKit.OAuth2Provider.new($microsoftCredentials)
var $office365:=cs.NetKit.Office365.new($oAuth2)Creare un evento
La funzione calendar.createEvent() consente di creare un nuovo evento in un calendario, sia nel calendario predefinito dell’utente corrente sia in un calendario specificato.
per Google API:
var $myEvent:={start: {}; end: {}}
// Create a one-hour meeting
$myEvent.start.date:=Current date
$myEvent.start.time:=Current time
$myEvent.end.date:=Current date
$myEvent.end.time:=Current time+3600
$myEvent.summary:="My event"
$myEvent.description:="This is an invitation"
$myEvent.attendees:=[{email: "myAttendeeAddress@mail.com"}]
// Meeting creation
$event:=$google.calendar.createEvent($myEvent)per MICROSOFT API:
var $myEvent:={start: {}; end: {}}
// Create a one-hour meeting
$myEvent.start.date:=Current date
$myEvent.start.time:=Current time
$myEvent.end.date:=Current date
$myEvent.end.time:=Current time+3600
$myEvent.isAllDay:=False
$myEvent.attendees:=[{emailAddress: {address: "myAttendeeAddress@mail.com"}; type: "required"}]
$myEvent.subject:="My event"
$myEvent.body:={content: "This is an invitation body"; contentType: "text"}
// Meeting creation
$event:=$office365.calendar.createEvent($myEvent)Aggiornamento di un evento
La funzione calendar.updateEvent() consente di modificare un evento esistente. È necessario fornire solo le proprietà che si desidera aggiornare; quelle esistenti non incluse rimangono invariate.
per Google API:
var $myUpdateEvent:={}
$myUpdateEvent.summary:="My updated subject"
// Meeting update
$event:=$google.calendar.updateEvent($myUpdateEvent)per MICROSOFT API:
var $myUpdateEvent:={}
$myUpdateEvent.subject:="My updated subject"
// Meeting update
$event:=$office365.calendar.updateEvent($myUpdateEvent)
Eliminare un evento
La funzione calendar.deleteEvent() rimuove un evento da un calendario. Se l’evento è una riunione, i partecipanti vengono avvisati automaticamente con un messaggio di cancellazione. Entrambi i comandi accettano gli stessi parametri:
per Google API:
$status:=$google.calendar.deleteEvent({eventId: $event.event.id})per MICROSOFT API:
$status:=$office365.calendar.deleteEvent({eventId: $event.event.id})Conclusione
Combinando le funzioni createEvent, updateEvent e deleteEvent di 4D NetKit, è possibile gestire completamente gli eventi del calendario Microsoft 365 o Google direttamente dalle applicazioni 4D. Che si tratti di un pianificatore di riunioni, di un sistema di prenotazione o di una dashboard personalizzata, questa integrazione offre ai vostri utenti strumenti potenti per rimanere organizzati e connessi.