Mehrstufige Listen in 4D Write Pro: Vollständige Kontrolle über Struktur, Nummerierung und Formatierung

Ab 4D 21 R3 können Sie in 4D Write Pro mithilfe von Formatvorlagen komplex strukturierte Aufzählungs- und nummerierte Listen mit mehreren Ebenen erstellen und diese in alle Formate, einschließlich docx, exportieren. Wenn Sie beispielsweise eine mehrstufige Liste erstellen möchten, deren Nummerierung sich automatisch anpasst, wenn Inhalte auf allen Ebenen entfernt oder hinzugefügt werden, oder wenn Sie Titel und Untertitel mit einheitlichen Stilen und Nummerierungen im gesamten 4D Write Pro-Dokument haben möchten, dann ist diese neue Funktion genau das Richtige für Sie. In diesem Blogbeitrag zeigen wir Ihnen genau, wie Sie mehrstufige Listen mithilfe von mehrstufigen Stylesheets erstellen.

Insbesondere erklären wir Ihnen, wie Sie Standardaktionen sowie Befehle verwenden, um die mehrstufigen Formatvorlagen zu verwalten.

 HDI_4DWP_MultiLevelStyleSheets

Verwaltung mehrstufiger Formatvorlagen über Standardaktionen

Wenn Sie das Ergebnis der untenstehenden Animation erzielen möchten, gehen Sie wie folgt vor:

• Schritt 1: Erstellen Sie ein Absatzformatvorlage mit einem Listenformat, das auf mehrere Absätze angewendet wird
• Schritt 2: Verwenden Sie die Standardaktion „ listLevelAppend“, um Ihrem Absatzformat neue Ebenen hinzuzufügen; auf diese Weise wandeln Sie eine einstufige Liste in eine mehrstufige Liste um
• Schritt 3: Verwenden Sie die Standardaktionen „ listLevelDec “ und „ listLevelInc“, um die Ebenen der ausgewählten Absätze entweder zu erhöhen oder zu verringern
• Schritt 4: Passen Sie das Format der Nummerierungszeichen mithilfe der Standardaktionen „ listConcatStringFormat “ und „ listNumberFormat“ an

Verwaltung mehrstufiger Formatvorlagen über 4D-Befehle

Bereits vor 4D 21 R3 bot 4D Write Pro Stilvorlagen an, die alle Absatzstile (einschließlich Listentypen) enthalten und auf Absätze angewendet werden können. Wir haben dieses bestehende Konzept erweitert, sodass es nun zur Erstellung mehrstufiger Listen genutzt werden kann.

Die mehrstufige Liste im folgenden Screenshot hat 3 Ebenen: eine Stammebene und 2 Unterebenen. Um dies zu erreichen, benötigen Sie 3 miteinander verknüpfte Absatzformatvorlagen: eine Formatvorlage für die Stammebene und 2 damit verknüpfte Formatvorlagen für die Unterebenen. So gehen Sie dabei konkret vor:

• Schritt 1: Erstellen Sie das Stilblatt für die oberste Ebene und die 2 damit verbundenen Stilblätter für die Unterebenen mit dem Befehl „ WP New style sheet “ in einer einzigen Codezeile. Diese 3 Stilblätter werden mit Standardwerten erstellt: „ wk list type “ = „ wk decimal “ und „ wk margin left “ = 0,75 cm * (Anzahl der vorherigen Ebenen)
• Schritt 2: Rufen Sie die drei verschiedenen Stylesheet-Objekte mit dem Befehl „ WP Get style sheet “ ab
• Schritt 3: Aktualisieren Sie den Stil des Stylesheets auf der obersten Ebene und jedes der Stylesheets auf den Unterebenen mit dem Befehl „ WP SET ATTRIBUTES  “, genau wie zuvor bei normalen Absatz-Stylesheets. Die spezifischen Stile, die wir in unserem Fall aktualisieren müssen, sind die folgenden: wk list style type, wk color, wk font size, wk font, wk font bold, wk list string format ltr und wk list format string concat (neues Attribut)
• Schritt 4: Wenden Sie jedes Stylesheet mit dem Befehl „ WP SET ATTRIBUTES “ auf die entsprechenden Absätze an, genau wie zuvor bei normalen Absatz-Stylesheets.
• Schritt 5 (optional): Sie können ein bestimmtes Stylesheet mit dem Befehl „ WP DELETE STYLE SHEET “ löschen, falls Sie Ihre Meinung geändert haben. Beachten Sie jedoch, dass beim Löschen des Stylesheets auf der obersten Ebene auch die damit verbundenen Stylesheets auf den untergeordneten Ebenen gelöscht werden.
• Schritt 6 (optional): Sie können Ihr 4D Write Pro-Dokument, das Ihre mehrstufige Liste enthält, mit dem Befehl „ WP EXPORT DOCUMENT “ in andere Formate exportieren: DOCX, SVG, PDF und HTML. In diesem Fall behält Ihre exportierte Liste die gleiche Hierarchie, die gleichen Stile und die gleiche Struktur bei, ohne dass die Einrückungen oder die Nummerierung verloren gehen.

Hier finden Sie den gesamten Code, den Sie benötigen, um die mehrstufige Liste mithilfe von mehrstufigen Stylesheets zu erstellen:

$spanishNovels:="Spanish Novels\n20th century\nCien años de soledad\nEl túnel\nFicciones\n"
$frenchNovels:="French Novels\n19th century\nLes Misérables\nMadame Bovary\nGerminal"
WP SET TEXT(WParea; $spanishNovels+$frenchNovels; wk append)

//Creating 3 multi-level style sheets
WP New style sheet(WParea; wk type paragraph; "MyList"; 3)

//Getting the multi-level style sheets objects
levelStyle1:=WP Get style sheet(WParea; "MyList"; 1)
levelStyle2:=WP Get style sheet(WParea; "MyList"; 2)
levelStyle3:=WP Get style sheet(WParea; "MyList"; 3)

//Modifying the paragraph styles of the multi-level style sheets
WP SET ATTRIBUTES(levelStyle1; \
{listStyleType: wk upper latin; color: "#1F3A5F"; fontSize: 18; font: "Tahoma"; listFont: "Tahoma"; fontBold: wk true})
WP SET ATTRIBUTES(levelStyle2; \
{listStyleType: wk decimal; listConcatStringFormat: True; color: "#52796F"; fontSize: 16; font: "Tahoma"; listFont: "Tahoma"; fontBold: wk true})
WP SET ATTRIBUTES(levelStyle3; \
{listStringFormatLtr: "(#)"; listConcatStringFormat: False; color: "Black"; fontSize: 12; font: "Times New Roman"; listFont: "Times New Roman"})

//Setting the  multi-level style sheets to the appropriate paragraphs
$paragraphs:=WP Get elements(WParea; wk type paragraph)
For ($i; 0; 9)
	If (($i=0) ' ($i=5))
		WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle1)
	Else 
		If (($i=1) ' ($i=6))
			WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle2)
		Else 
			WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle3)
		End if 
	End if 
End for 

Importieren und Exportieren von mehrstufigen Listen

Mehrstufige Listen sind nicht nur in 4D Write Pro verfügbar, sie bleiben auch beim Exportieren oder Importieren in andere Formate erhalten.

Wenn Sie ein 4D Write Pro-Dokument exportieren, das mehrstufige Listen enthält, behält das resultierende Dokument die gleiche Listenstruktur und die gleichen Ebenen in allen unterstützten Exportformaten bei, einschließlich DOCX, PDF, SVG, HTML-Webseite (vollständig) und HTML-MIME. Das bedeutet, dass Ihre mehrstufige Nummerierung (Stammebene und Unterebenen) konsistent bleibt, ohne dass die Liste abgeflacht wird oder Einrückungen und Hierarchien verloren gehen.

Auch beim Importieren eines DOCX -Dokuments, das eine mehrstufige Liste enthält, bewahrt 4D Write Pro die gleiche mehrstufige Struktur im resultierenden 4D Write Pro-Dokument.
Sowohl flache als auch mehrstufige Listen werden mit intakter Hierarchie importiert, und Sie können sie weiterhin programmgesteuert oder über Standardaktionen bearbeiten.

Fazit

Mit mehrstufigen Formatvorlagen in 4D Write Pro wird das Erstellen strukturierter und professioneller Dokumente einfacher und leistungsfähiger denn je. Ganz gleich, ob Sie komplexe Gliederungen erstellen, hierarchische Informationen organisieren oder eine konsistente Nummerierung in umfangreichen Dokumenten sicherstellen möchten – diese Funktion gibt Ihnen die volle Kontrolle über die Struktur und Darstellung Ihrer Inhalte.

Durch die Kombination von Standardaktionen für die interaktive Bearbeitung und 4D-Befehlen für die programmatische Steuerung können Sie mehrstufige Listen einfach erstellen, verwalten und pflegen, die sich automatisch an die Entwicklung Ihres Dokuments anpassen. Noch besser: Diese Listen behalten ihre Struktur und Formatierung beim Exportieren oder Importieren von Dokumenten bei, was eine nahtlose Interoperabilität mit Formaten wie DOCX, PDF, HTML und anderen gewährleistet.

Während 4D 21 R3 bereits leistungsstarke Funktionen zur programmgesteuerten Verwaltung mehrstufiger Listen sowie über Standardaktionen bietet, wird in 4D 21 R4 eine spezielle Benutzeroberfläche eingeführt, die eine intuitivere Handhabung dieser Funktionen ermöglicht und das Gesamterlebnis weiter verbessert.

Weitere Informationen zu Listen in 4D Write Pro finden Sie in der Dokumentation. Bei Fragen und Anmerkungen besuchen Sie bitte das 4D-Forum.