Víceúrovňové seznamy v 4D Write Pro: Plná kontrola nad strukturou, číslováním a stylem

Od verze 4D 21 R3 můžete v aplikaci 4D Write Pro pomocí stylových šablon vytvářet propracované strukturované seznamy s odrážkami a číslované seznamy s více úrovněmi a exportovat je do všech formátů, včetně docx. Pokud například chcete vytvořit víceúrovňový seznam, jehož číslování se automaticky upraví při odstranění nebo přidání obsahu na všech úrovních, nebo pokud chcete mít v celém dokumentu 4D Write Pro nadpisy a podnadpisy se jednotným stylem a číslováním, pak je tato nová funkce přesně to, co potřebujete. V tomto blogovém příspěvku vám ukážeme, jak přesně vytvořit víceúrovňové seznamy pomocí víceúrovňových stylových šablon.

Konkrétně vysvětlíme, jak používat standardní akce i příkazy pro správu víceúrovňových stylů.

 HDI_4DWP_MultiLevelStyleSheets

Správa víceúrovňových stylů pomocí standardních akcí

Pokud chcete dosáhnout toho, co je v animaci níže, postupujte takto:

• Krok 1: Vytvořte stylový list odstavce s typem seznamu, který je aplikován na několik odstavců
• Krok 2: Použijte standardní akci „ listLevelAppend“ (Přidat úroveň do seznamu), abyste do svého stylu odstavce přidali nové úrovně; tímto způsobem přejdete z jednoúrovňového seznamu na víceúrovňový seznam
• Krok 3: Použijte standardní akce „ listLevelDec “ a „ listLevelInc“, abyste zvýšili nebo snížili úroveň vybraných odstavců
• Krok 4: Upravte formát číslovacích značek pomocí standardních akcí „ listConcatStringFormat “ a „ listNumberFormat“

Správa víceúrovňových stylů pomocí příkazů 4D

Již před verzí 4D 21 R3 nabízel 4D Write Pro styly, které mohou zahrnovat všechny styly odstavců (včetně typů seznamů) a které lze aplikovat na odstavce. Tento stávající koncept jsme vylepšili tak, aby jej bylo možné použít k vytváření víceúrovňových seznamů.

Víceúrovňový seznam na níže uvedeném snímku obrazovky má 3 úrovně: jednu kořenovou a 2 podúrovně. K jeho vytvoření potřebujete 3 styly odstavců, které spolu souvisejí: jeden styl kořenové úrovně a 2 styly podúrovní, které s ním souvisejí. Zde je postup, jak toho dosáhnout v konkrétních krocích:

• Krok 1: Vytvořte stylový list kořenové úrovně a 2 s ním související stylové listy podúrovní pomocí příkazu „ WP New style sheet “ v jednom řádku kódu. Tyto 3 stylové listy jsou vytvořeny s výchozími hodnotami: „ wk list type “ = „ wk decimal “ a „ wk margin left “ = 0,75 cm* (počet předchozích úrovní)
• Krok 2: Získejte 3 různé objekty stylových listů pomocí příkazu WP Get style sheet
• Krok 3: Aktualizujte styl kořenového stylu a každého z podřízených stylů pomocí příkazu WP SET ATTRIBUTES  , stejně jako jste to udělali dříve u běžných stylů odstavců. Konkrétní styly, které v našem případě potřebujeme aktualizovat, jsou následující: wk list style type, wk color, wk font size, wk font, wk font bold, wk list string format ltr a wk list format string concat (nový atribut)
• Krok 4: Použijte každý stylový list na odpovídající odstavce pomocí příkazu WP SET ATTRIBUTES  , stejně jako jste to udělali dříve u běžných stylových listů odstavců.
• Krok 5 (volitelný): Pokud si to rozmyslíte, můžete konkrétní stylový list odstranit pomocí příkazu WP DELETE STYLE SHEET  . Nezapomeňte však, že pokud odstraníte stylový list na kořenové úrovni, budou odstraněny i stylové listy na podúrovni, které s ním souvisejí.
• Krok 6 (volitelný): Dokument 4D Write Pro obsahující víceúrovňový seznam můžete pomocí příkazu WP EXPORT DOCUMENT exportovat do jiných formátů: DOCX, SVG, PDF a HTML. V tomto případě si exportovaný seznam zachová stejnou hierarchii, styly a strukturu, aniž by došlo ke ztrátě odsazení nebo číslování.

Zde je veškerý kód, který potřebujete k vytvoření víceúrovňového seznamu pomocí víceúrovňových stylů:

$spanishNovels:="Spanish Novels\n20th century\nCien años de soledad\nEl túnel\nFicciones\n"
$frenchNovels:="French Novels\n19th century\nLes Misérables\nMadame Bovary\nGerminal"
WP SET TEXT(WParea; $spanishNovels+$frenchNovels; wk append)

//Creating 3 multi-level style sheets
WP New style sheet(WParea; wk type paragraph; "MyList"; 3)

//Getting the multi-level style sheets objects
levelStyle1:=WP Get style sheet(WParea; "MyList"; 1)
levelStyle2:=WP Get style sheet(WParea; "MyList"; 2)
levelStyle3:=WP Get style sheet(WParea; "MyList"; 3)

//Modifying the paragraph styles of the multi-level style sheets
WP SET ATTRIBUTES(levelStyle1; \
{listStyleType: wk upper latin; color: "#1F3A5F"; fontSize: 18; font: "Tahoma"; listFont: "Tahoma"; fontBold: wk true})
WP SET ATTRIBUTES(levelStyle2; \
{listStyleType: wk decimal; listConcatStringFormat: True; color: "#52796F"; fontSize: 16; font: "Tahoma"; listFont: "Tahoma"; fontBold: wk true})
WP SET ATTRIBUTES(levelStyle3; \
{listStringFormatLtr: "(#)"; listConcatStringFormat: False; color: "Black"; fontSize: 12; font: "Times New Roman"; listFont: "Times New Roman"})

//Setting the  multi-level style sheets to the appropriate paragraphs
$paragraphs:=WP Get elements(WParea; wk type paragraph)
For ($i; 0; 9)
	If (($i=0) ' ($i=5))
		WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle1)
	Else 
		If (($i=1) ' ($i=6))
			WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle2)
		Else 
			WP SET ATTRIBUTES($paragraphs[$i]; wk style sheet; levelStyle3)
		End if 
	End if 
End for 

Import a export víceúrovňových seznamů

Víceúrovňové seznamy nejsou k dispozici pouze v aplikaci 4D Write Pro, ale zachovávají se i při exportu nebo importu do jiných formátů.

Při exportu dokumentu 4D Write Pro obsahujícího víceúrovňové seznamy si výsledný dokument zachovává stejnou strukturu seznamu a úrovně ve všech podporovaných formátech exportu, včetně DOCX, PDF, SVG, kompletní webové stránky HTML a HTML-MIME. To znamená, že vaše víceúrovňové číslování (kořenová úroveň a podúrovně) zůstává konzistentní, aniž by došlo ke zploštění seznamu nebo ke ztrátě odsazení a hierarchie.

Také při importu dokumentu DOCX, který obsahuje víceúrovňový seznam, zachová 4D Write Pro stejnou víceúrovňovou strukturu ve výsledném dokumentu 4D Write Pro.
Ploché i víceúrovňové seznamy se importují s neporušenou hierarchií a můžete je dále upravovat programově nebo pomocí standardních akcí.

Závěr

Díky víceúrovňovým stylovým šablonám v 4D Write Pro je vytváření strukturovaných a profesionálních dokumentů jednodušší a výkonnější než kdykoli předtím. Ať už vytváříte složité osnovy, organizujete hierarchické informace nebo zajišťujete konzistentní číslování v rozsáhlých dokumentech, tato funkce vám poskytuje plnou kontrolu nad strukturou a prezentací vašeho obsahu.

Kombinací standardních akcí pro interaktivní úpravy a příkazů 4D pro programové ovládání můžete snadno vytvářet, spravovat a udržovat víceúrovňové seznamy, které se automaticky přizpůsobují vývoji vašeho dokumentu. Ještě lepší je, že si tyto seznamy zachovávají svou strukturu a formátování při exportu nebo importu dokumentů, což zajišťuje hladkou interoperabilitu s formáty jako DOCX, PDF, HTML a dalšími.

Zatímco 4D 21 R3 již poskytuje výkonné funkce pro správu víceúrovňových seznamů programově a prostřednictvím standardních akcí, ve verzi 4D 21 R4 bude zavedeno speciální uživatelské rozhraní pro intuitivnější práci s těmito funkcemi, což dále zlepší celkový uživatelský zážitek.

Další podrobnosti o seznamech v 4D Write Pro najdete v dokumentaci a s dotazy a připomínkami se obraťte na fórum 4D.