Um benutzerfreundliche Dokumente zu erstellen, müssen Sie oft eine Gitternetzlinie oder eine Kopfzeile ausblenden, bestimmte Zellen schützen oder einfach die Linienfarbe ändern, um die Corporate Identity zu wahren. Mit 4D v18 R3 können Sie all dies und mehr mit dem neuen VP SET SHEET OPTIONS Befehl.
Ein Blatt schützen
Der Schutz eines Arbeitsblatts verhindert, dass die darin enthaltenen Zellen bearbeitet werden können. Standardmäßig sind alle Zellen eines 4D View Pro Dokuments als gesperrt markiert. Wenn Sie Ihr gesamtes Arbeitsblatt schützen wollen, brauchen Sie nur zu schreiben:
$options:=New object
// Activate protection
$options .isProtected:=True
// Apply protection on the current sheet
VP SET SHEET OPTIONS ("ViewProArea";$options)
Wenn Sie den Benutzern erlauben wollen, bestimmte Zellen zu bearbeiten, können Sie das Arbeitsblatt schützen und nur die Zellen freischalten, die der Benutzer bearbeiten kann.
Wie das vorherige Beispiel zeigt, schützt die Einstellung der Option isProtected Option auf True das gesamte Arbeitsblatt. Wenn Sie alle Zellen mit Ausnahme des Bereichs C5:D10 schützen möchten, markieren Sie den Bereich einfach als nicht gesperrt:
$options:=New object
// Activate protection
$options .isProtected:=True
// Apply protection on the current sheet
VP SET SHEET OPTIONS ("ViewProArea";$options)
// mark cells C5:D10 as 'unlocked'
VP SET CELL STYLE (VP Cells ("ViewProArea";2;4;2;6);New object("locked";False))
Die Eigenschaft protectionOptions kann verwendet werden, um festzulegen, was der Benutzer ändern darf, z. B. Größenänderung, Ziehen, Einfügen oder Löschen von Zeilen und Spalten usw.
Sie möchten Ihr Dokument schützen, aber den Benutzern erlauben, die Größe von Zeilen und Spalten zu ändern? Sie können dies schreiben:
$options:=New object
// Activate protection
$options .isProtected:=True
$options .protectionOptions:=New object
// Allow user to resize rows
$options .protectionOptions.allowResizeRows=True;
// Allow user to resize columns
$options .protectionOptions.allowResizeColumns=True;
// Apply protection on the current sheet
VP SET SHEET OPTIONS ("ViewProArea";$options)
Ändern Sie das Erscheinungsbild Ihres Arbeitsblatts
Farben ändern
Mit dem Befehl VP SET SHEET OPTIONS können Sie auch die Farben der Tabulatoren, der eingefrorenen Linien, der Gitternetzlinien, des Hintergrunds und des Rahmens einer Auswahl auf Ihrem Arbeitsblatt anpassen.
$options:=New object
// Customize color of Sheet 1 tab
$options .sheetTabColor:="Schwarz"
$options .gridline:=New object("color"; "Purple")
$options .selectionBackColor:="rgba(255,128,0,0.4)"
// Use rgba() for the transparency. Here : 40% transparency
$options.selectionBorderColor:="Gelb"
$options .frozenlineColor:="Gold"
VP SET SHEET OPTIONS ("ViewProArea";$options;0)
// Customize color of Sheet 2 tab
$options.sheetTabColor:="rot"
VP SET SHEET OPTIONS ("ViewProArea";$options;1)
// Customize color of Sheet 3 tab
$options.sheetTabColor:="blau"
VP SET SHEET OPTIONS ("ViewProArea";$options;2)
Hier ist das Ergebnis:
Elemente ausblenden
VP SET SHEET OPTIONS Mit dem Befehl Rahmen können Sie sogar die Sichtbarkeit der Gitternetzlinien und der Zeilen- und Spaltenüberschriften des Arbeitsblatts steuern:
$options:=New object
$options .gridline:=New object()
$options .gridline.showVerticalGridline:=False
$options .gridline.showHorizontalGridline:=False
$options .rowHeaderVisible:=False
$options .colHeaderVisible:=False
VP SET SHEET OPTIONS ("ViewProArea";$options)
Werfen Sie einen Blick auf das Ergebnis:
workSheet Area Offset
Da Rahmen an der Außenseite von Zellen gezeichnet werden, können Sie mit der Eigenschaft sheetAreaOffset Eigenschaft verwenden, um sicherzustellen, dass das gesamte Arbeitsblatt gerendert wird:
$options:=New object
$options .sheetAreaOffset:=New object
$options .sheetAreaOffset.left:=2
$options .sheetAreaOffset.top:=2
VP SET SHEET OPTIONS ("ViewProArea";$options)
Weitere Informationen finden Sie im Doc Center, und vergessen Sie nicht, diesen Befehl mit dem obigen HDI auszuprobieren.