4D View Pro: Import zpětného volání zajišťuje, že vlastní funkce jsou plně vyřešeny

Import dokumentů je běžnou úlohou při práci s aplikací 4D View Pro. Pokud však tyto dokumenty obsahují vlastní funkce, může být náročné určit, kdy jsou všechny výpočty dokončeny před provedením akcí, jako je tisk nebo uložení. Pro vyřešení tohoto problému 4D 20 R9 zajišťuje, aby se zpětný vzorec importních příkazů provedl až po úplném vyřízení všech vlastních funkcí. Toto vylepšení poskytuje větší kontrolu a spolehlivost při práci s importovanými dokumenty 4D View Pro.

HDI 4DVP Koncové načtení vlastní funkce

Aktualizované příkazy pro import

Následující importní příkazy nyní zaručují, že jejich zpětné volání se neprovede, dokud nebudou zodpovězeny všechny vlastní funkce:

• VP IMPORT DOCUMENT
• VP IMPORT FORM BLOB
• VP IMPORT FROM OBJECT

Pokud například načítáte velký dokument s mnoha vlastními funkcemi do oblasti mimo obrazovku, čekáte na dokončení všech výpočtů a poté jej exportujete, budete muset nastavit třídu takto: „Třída:

property pdfPath : Text
property autoQuit:=False

Class constructor($pdfPath : Text)
   This.pdfPath:=$pdfPath
	
  // This function is called on each event for the offscreen area
Function onEvent
   Case of 
      : (FORM Event.code=On VP Ready)
         var $largeDocument4VP:="c:\\tmp\\mylargedocument.sjs"
			
         // Exports document in PDF called at the end of the import
         var $callback:=Formula(VP EXPORT DOCUMENT(This.area;\
            This.pdfPath; {formula: Formula(ACCEPT)}))
			
         // Document import with recalculation of all the formulas
         VP IMPORT DOCUMENT(This.area; $largeDocument4VP;\
            {formula: $callback; sjsOptions: {fullRecalc: True}})
			
			
      : (FORM Event.code=On URL Loading Error)
         CANCEL		
   End case 

a zavolat ji v oblasti mimo obrazovku:

// Creation of the offscreen parameter object to init the offscreen area
$offScreenParameter:=cs.OffScreenParameterClass.new($pdfPath)

// Creation of the offscreen area
VP Run offscreen area($offScreenParameter)

Aktualizace příkazů VP FLUSH COMMANDS

Zavedli jsme také mechanismus pro čekání na ukončení asynchronních výpočtů v oblasti VP FLUSH COMMAND. Stejným způsobem jako u importů můžete nyní přidat vzorec jako parametr, který bude volán na konci výpočtů.

Pokud například přidáte programováním několik volání vlastních funkcí a počkáte na jejich výpočty při exportu dokumentu:

// Adds an asynchronous calculation
VP SET FORMULA(VP Cell($area; 1; 2); "my4DFunction(1)")
// Waits for the calculation to finish and exports the document
VP FLUSH COMMANDS("ViewProArea"; Formula(VP EXPORT DOCUMENT("ViewProarea"; "c:\\tmp\\vpflush.xlsx")))

Závěr:

Tato aktualizace zjednodušuje manipulaci s importy 4D View Pro pomocí vlastních funkcí a usnadňuje tisk, ukládání nebo zpracování dokumentů až po dokončení všech výpočtů.