Trabajar con eventos de calendario es una parte esencial de muchas aplicaciones empresariales. Ya sea que esté organizando una reunión de equipo o gestionando el ciclo de vida de un evento, es esencial poder crear, actualizar y eliminar eventos mediante programación.
En esta entrada de blog, veremos cómo realizar estas operaciones utilizando las clases Office365.calendar o Google.calendar proporcionadas en 4D 20 R10, impulsadas por las APIs Microsoft Graph y Google Calendar.
Gestión de eventos de calendario HDI
Vamos a explorar lo simple que es crear, actualizar y eliminar una reunión en Microsoft o Google Calendar utilizando 4D NetKit, con el ejemplo siguiente.
Conexión a la cuenta
Como es habitual, antes de utilizar las APIs de Google o Microsoft, crearemos un objeto de conexión OAuth 2.0:
Para Google API:
var $oAuth2:=cs.NetKit.OAuth2Provider.new($googleCredentials)
var $google:=cs.NetKit.Google.new($oAuth2)
Para Microsoft API:
var $oAuth2:=cs.NetKit.OAuth2Provider.new($microsoftCredentials)
var $office365:=cs.NetKit.Office365.new($oAuth2)
Crear un evento
La función calendar.createEvent() permite crear un nuevo evento en un calendario, ya sea en el calendario predeterminado del usuario actual o en un calendario especificado.
para Google API:
var $myEvent:={start: {}; end: {}}
// Create a one-hour meeting
$myEvent.start.date:=Current date
$myEvent.start.time:=Current time
$myEvent.end.date:=Current date
$myEvent.end.time:=Current time+3600
$myEvent.summary:="My event"
$myEvent.description:="This is an invitation"
$myEvent.attendees:=[{email: "myAttendeeAddress@mail.com"}]
// Meeting creation
$event:=$google.calendar.createEvent($myEvent)
para MICROSOFT API:
var $myEvent:={start: {}; end: {}}
// Create a one-hour meeting
$myEvent.start.date:=Current date
$myEvent.start.time:=Current time
$myEvent.end.date:=Current date
$myEvent.end.time:=Current time+3600
$myEvent.isAllDay:=False
$myEvent.attendees:=[{emailAddress: {address: "myAttendeeAddress@mail.com"}; type: "required"}]
$myEvent.subject:="My event"
$myEvent.body:={content: "This is an invitation body"; contentType: "text"}
// Meeting creation
$event:=$office365.calendar.createEvent($myEvent)
Actualizar un evento
La función calendar.updateEvent() permite modificar un evento existente. Sólo tiene que indicar las propiedades que desea actualizar; las no incluidas permanecen inalteradas.
para la API de Google:
var $myUpdateEvent:={}
$myUpdateEvent.summary:="My updated subject"
// Meeting update
$event:=$google.calendar.updateEvent($myUpdateEvent)
para la API de MICROSOFT:
var $myUpdateEvent:={}
$myUpdateEvent.subject:="My updated subject"
// Meeting update
$event:=$office365.calendar.updateEvent($myUpdateEvent)
Eliminar un evento
La función calendar.deleteEvent() elimina un evento de un calendario. Si el evento es una reunión, se notifica automáticamente a los asistentes con un mensaje de cancelación. Ambos comandos reciben los mismos parámetros:
para Google API:
$status:=$google.calendar.deleteEvent({eventId: $event.event.id})
para MICROSOFT API:
$status:=$office365.calendar.deleteEvent({eventId: $event.event.id})
Conclusión
Combinando las funciones createEvent, updateEvent, y deleteEvent de 4D NetKit, puede gestionar eventos de Microsoft 365 o del calendario de Google directamente desde sus aplicaciones 4D. Ya sea que esté construyendo un programador de reuniones, un sistema de reservas o un panel de control personalizado, esta integración ofrece a sus usuarios herramientas poderosas para mantenerse organizados y conectados.
Por el momento, no se pueden publicar comentarios en esta entrada.