Codificar un rango en 4D View Pro

4D v17 R4 trae nuevas características a 4D View Pro y una de ellas es la creación de rangos con código.

En primer lugar, debe definir un objeto de rango para manipular sus celdas mediante programación. Puede hacerlo en 4D View Pro con los siguientes nuevos comandos: VP Cell, VP Cells, VP Column, VP Row, VP All y VP Combine ranges.

Un objeto de rango puede definir

• una celda o un grupo de celdas,
• una columna o un grupo de columnas,
• una fila o un grupo de filas
• todas las celdas de una hoja.

definir una celda o un grupo de celdas

Para definir las coordenadas de una sola celda, utilice el VP Cell para definir las coordenadas de una sola celda:

$column:=3 //column of beginning cell
$row :=5 //row of beginning cell
$sheet :=2 // specific workbook sheet
$cellObj1 :=VP Cell ("ViewProArea";$column;$row) // cell D6 (current sheet)
$cellObj2 :=VP Cell ("ViewProArea";$column;$row;$sheet) // cell D6 sheet 3


Tenga en cuenta que el índice de la fila, el índice de la columna y el índice de la hoja comienzan en 0. ¡Por lo tanto, las coordenadas de la primera celda superior izquierda son (0;0)!

Un grupo de celdas se define básicamente haciendo referencia a la celda superior izquierda y al recuento de filas y celdas. Pase esta información al comando VP Cells comando:

$column:=3 //column of beginning cell
$row :=5 //row of beginning cell
$columnCount :=2 // total number of columns
$rowCount :=3 // total number of rows
$sheet :=2 // specific workbook sheet
$cellsObj1 :=VP Cells ("ViewProArea";$column;$row;$columnCount;$rowCount) // cells D6 to E8 (current sheet)
$cellsObj2 :=VP Cells ("ViewProArea";$column;$row;$columnCount;$rowCount;$sheet) // cells D6 to E8 on sheet 3


definir una columna o un grupo de columnas

Para definir la coordenada de una columna, pase el índice de la columna al comando VP Column para definir la coordenada de una columna. Si necesita definir varias columnas contiguas, añada un recuento de columnas después del índice de la columna:

$column:=3 // beginning column
$columnCount :=2 // total number of columns
$sheet :=2 // specific workbook sheet
$colObj1 :=VP Column ("ViewProArea";$column) // column D (current sheet)
$colObj2 :=VP Column ("ViewProArea";$column;$columnCount) // column D + column E (current sheet)
$colObj3 :=VP Column ("ViewProArea";$column;$columnCount;$sheet ) // column D + column E sheet 3

definir una fila o un grupo de filas

Para definir las coordenadas de una fila, pase el índice de la columna al comando VP Row. Si necesita definir varias filas contiguas, añada un recuento de filas después del índice de filas:

$row:=5 // beginning row
$rowCount :=3 // total number of rows
$sheet :=2 // specific workbook sheet
$rowObj1 :=VP Row ("ViewProArea";$row) // row 6
$rowObj2 :=VP Row ("ViewProArea";$row;$rowCount) // row 6 + row 7 + row 8
$rowObj3 :=VP Row ("ViewProArea";$row;$rowCount;$sheet ) // row 6 + row 7 + row 8 sheet 2

definir un rango de celdas irregular

Un rango de celdas irregular es cuando necesita combinar varios grupos de celdas separados (discontinuos) dentro del mismo rango. Para ello, cree un rango individual para cada grupo continuo, y luego páselos todos en parámetro al VP Combine ranges comando:

$combine:=VP Combine ranges ($cellObj1;$colObj1;$rowObj1;rowObj2;cellsObj2 )